Checking the order of accuracy for the built-in ODE solver rk

The Maxima documentation says the numerical ODE solver in the command rk() is  fourth order accurate.  I ran a little test to confirm that.

Here’s the html export of the Maxima session, and a screenshot of the punchline:

RKorder4

Advertisements

Numerical Solutions of 2D and 3D ODE systems and phase plots

I most often use the built-in solvers in MATLAB (or the freeware alternative FreeMat) for numerical solutions of ODE systems.  They are easy to call and MATLAB graphical output is very flexible and of high quality.  That said, if I’m already working in Maxima to study stability behavior and equilibrium solutions, it’s fun to stay in the same window for  a numerical solution.

Here’s an example:  a damped, driven hard spring oscillator, written in phase space variables

\dot{y}=z, \dot{z}=-y^3-y-z/10 + 3/10\cos(t)

It’s straight-forward enough to run the Maxima numerical solver rk on this equation.  Extracting the numerical values of the two dependent variables is a little bit of a drag, requiring a call to makelist.  To make a plot in phase space, here’s a one-line function that is so easy to call:

/* wxphaseplot2d takes the output of s: rk([rhs1,rhs2]) 
   and  plots in phase space */
wxphaseplot2d(s):=wxplot2d([discrete,makelist([p[2],p[3]],p,s)],[xlabel,""],[ylabel,""]);

Here’s how it works on the above  example with a cute phase-space solution curve:

phaseheart

And here’s another famous phase curve—the solution of the Brusselator:

brusselatorphase

 

And can I just point out how analytically solving for the equilibrium solution has a very similar calling sequence — so easy that there’s no reason not to do it every time you want a numerical solution, and vice versa!

 

brusselator_eqsoln

 

Update!  Here’s a 3D phase plotter

/* wxphasplot3d takes the output of s: rk([rhs1,rhs2,rhs3]) and plots in phase space */

wxphaseplot3d(s):=wxdraw3d(point_type=0,point_size=.3,points_joined=true,points(makelist([p[2],p[3],p[4]],p,s)));

A classical example of 3D phase space trajectory curves, the Lorenz strange attractor system:

lorenz3D

Path Integrals

For my multivariable calculus class, I wanted an easy-to-call suite of symbolic integrators for path integrals of the form

\int_C f(x,y) dr,

\int_C {\bf F}(x,y)\cdot d{\bf r} = \int_C \langle P(x,y), Q(x,y) \rangle\cdot \langle dx, dy \rangle, or

\int_C {\bf F}(x,y,z)\cdot d{\bf r} = \int_C \langle P(x,y,z), Q(x,y,z), R(x,y,z) \rangle\cdot \langle dx, dy, dz \rangle.

My overarching design idea was that the input arguments needed to look the way they do when I teach the course:

  • a scalar field f(x,y):R^2 \rightarrow R or a vector field  {\bf F}(x,y): R^2 \rightarrow R^2 or {\bf F}(x,y,z): R^3 \rightarrow R^3
  • a curve C defined by a vector-valued function {\bf r}(t): R \rightarrow R^n, a\le t \le b where n=2,3 as appropriate.

It took me a while to work out how to evaluate the integrand along the path within my function.  Things that worked fine on the command line failed when embedded into a batch file to which I passed functions as arguments.  I ended up using subst, one variable at a time.  I’d like to be able to do this in a single command which can detect whether we’re in 2 or 3 dimensions so that I don’t need separate commands.

For now, here’s what I came up with along with some illustrative examples taken from Paul’s online math notes, that show how to call these new commands I, I2 and I3.

/* path integral of a scalar integrand f(x,y) on path r(t) in R^2, t from a to b */
 I(f,r,t,a,b):=block(
 [f1,f2,dr,Iout],
 f1:subst(x=r[1],f),
 f2:subst(y=r[2],f1),
 dr:sqrt(diff(r,t).diff(r,t)),
 Iout: integrate(f2*dr,t,a,b),
 Iout
 );
/* path integral of a vector integrand F(x,y) on path r(t) in R^2, t from a to b */
 I2(H,r,t,a,b):=block(
 [H1,H2,I],
 H1:subst(x=r[1],H),
 H2:subst(y=r[2],H1),
 I: integrate( H2.diff(r,t),t,a,b),
 I
 );
/* path integral of a vector integrand F(x,y,z) on path r(t) in R^3, t from a to b */
 I3(H,r,t,a,b):=block(
 [H1,H2,H3,I],
 H1:subst(x=r[1],H),
 H2:subst(y=r[2],H1),
 H3:subst(z=r[3],H2),
 I: integrate( H3.diff(r,t),t,a,b),
 I
 );

PathIntegrals

Here’s an update:  a related maxima function for evaluating a complex integral

\int_\Gamma f(z) dz

where f: C \rightarrow C and the curve \Gamma is given by r: R \rightarrow C.

/* path integral of a complex integrand f(z): C --> C, on path z(t): R --> C, t from a to b */
IC(f,r,t,a,b):=block(
[f1,dz,Iout],
f1:subst(z=r,f),
dz:diff(r,t),
Iout: integrate(f1*dz,t,a,b),
Iout
);

ComplexIntegral

:=, ”(), define and div, grad, curl

I recently posted about : and :=  for defining functional expressions.  I’m starting to enjoy these emoji-like constructions 😉

This is another  colon-equals post.  This time for defining functions involving the maxima differentiation command diff.

Notice below that if we define a function with :=, the naive use of :=diff doesn’t produce a derivative with the expected results upon evaluation.

colonequaldiff

In fact, it’s a good thing that :=diff works like that.  The error with fp(3) above comes from the fact that we’ve actually defined an operator that differentiates the function with respect to the argument we pass…in the case above, differentiating with respect to the symbol u makes sense, while differentiating with respect to the constant 3 doesn’t.

So how to make the derivative function do what we want?  Two ways, that are subtly different, in ways I’m not completely sure of.  More about that when I learn more :-).

First is define,

definediff

Also you can use    ”()       quote-quote with parens around the whole right hand side:

quotequotediff

I used define to write functions for vector valued 3D curves in an earlier post.   In figuring this out, I also learned that the :=diff form is really useful.  Below are three little functions in which I use :=diff to define the vector calculus operators grad, div and curl.  Notice that we pass the function f as an argument, and the :=diff form allows Maxima to differentiate them behind the scenes and return the results of the grad, div, and curl operators as you’d expect. These versions of div, grad and curl behave differently, and for me more as expected, than the functions of those names included in the Maxima vect package.  You can download the .mac file here.

/* Three Maxima functions for the multivariable calculus operators  grad, div, and curl
TheMaximaList.org, 2016
*/

grad(f,x,y,z):=[diff(f,x),diff(f,y),diff(f,z)]$

div(f,x,y,z):=diff(f[1],x)+diff(f[2],y)+diff(f[3],z)$

curl(f,x,y,z):=[ diff(f[3],y)-diff(f[2],z),
diff(f[1],z)-diff(f[3],x),
diff(f[2],x)-diff(f[1],y) ]$

Here is a screenshot showing how to call these functions:

divgradcurl

Curvature, T, N, & B

A classic topic in multivariable calculus involves the study of a vector valued function {\bf r}(t)=\langle x(t),y(t),z(t) \rangle using the three canonical unit vectors —  the tangent vector {\bf T}(t), the normal vector {\bf N}(t), and the Binormal vector {\bf B}(t) — and the scalar curvature \kappa(t).

Here are maxima functions that compute these, called
unitT, unitN, unitB, and curvature.  For a vector valued function {\bf r}(t), these are called as

T(t):=unitT(r(t),t);

You can download the .mac file here.

/* unitT computes the unit tangent vector for a vector valued function
of a scalar variable r(t)=[x(t),y(t),z(t)] */

unitT(r,t):=
block([rp,rpn,T],
define(rp(t),diff(r,t)),
define(rpn(t),sqrt(rp(t).rp(t))),
define(T(t),rp(t)/rpn(t)),
trigsimp(T(t))
)$

/* unitN computes the unit normal vector for a vector valued function
of a scalar variable r(t)=[x(t),y(t),z(t)]
unitN requires unitT */

unitN(r,t):=
block([T,Tp,Tpn,N],
define(T(t),unitT(r,t)),
define(Tp(t),diff(T(t),t)),
define(Tpn(t),sqrt(Tp(t).Tp(t))),
define(N(t),Tp(t)/Tpn(t)),
trigsimp(N(t))
)$

/* unitB computes the unit normal vector for a vector valued function
of a scalar variable r(t)=[x(t),y(t),z(t)]
unitB requires unitT and unitN */

unitB(r,t):=
block([T,N,B],
define(T(t),unitT(r,t)),
define(N(t),unitN(r,t)),
define(B(t),[T(t)[2]*N(t)[3]-T(t)[3]*N(t)[2],
T(t)[3]*N(t)[1]-T(t)[1]*N(t)[3],
T(t)[1]*N(t)[2]-T(t)[2]*N(t)[1]]),
trigsimp(B(t))
)$

/* curvature computes the curvature
curvature requires unitT */

curvature(r,t):=
block([T,Tdot,rdot,K],
define(T(t),unitT(r,t)),
define(Tdot(t),diff(T(t),t)),
define(rdot(t),diff(r,t)),
define(K(t),trigsimp(sqrt(Tdot(t).Tdot(t)/rdot(t).rdot(t)))),
K(t)
)$

 

$latex \int x^2 dx$

I’m testing the latex math-mode utility in WordPress.com.  The first thing to know is that based on the way the title of this post appears, the latex utility doesn’t work in post titles.

The rub here is that MathJax would be the natural solution, but WordPress.com isn’t compatible with JavaScript.  

That leaves us with $, followed by the word latex, followed by my latex markup, followed by a closing $ , which I illustrate  below with a screenshot because I don’t know how to quote a string verbatim in WordPress:

preform

This works OK as inline style math \int x^2 dx and I think we could simulate display math mode like this with manual paragraph centering and with the optional size argument &s=1 inside the dollar signs (the default size is 0)

\int x^2 dx

and then back to inline for f(x).

And there it is.

The official guide to the  WordPress \LaTeX utility  can be found here.

Functions, :, and :=

I’m really posting this for myself to act as a big paperweight.  Whenever I forget about :=  and : for functions in Maxima, I can refer to this page.

The gist:

  • g(x):=x^2  results in a function you can evaluate as g(3)
  • f: x^2 results in an expression you can evaluate with ev(f,x=3)
  • ev works with both:  ev(g(x),x=3)  or ev(f,x=3)
  • also subst(x=3,f) and subst(x=3,g(x))
  • based on our definition, g doesn’t have a meaning…only  g(x) does
  • likewise, f(3) doesn’t have a meaning here…only the symbol f does
  • finally h:=x^2 gives an error — explicit dependent variable needed with :=

colonequals

subst

colonequalserror